home *** CD-ROM | disk | FTP | other *** search
/ C/C++ Users Group Library 1996 July / C-C++ Users Group Library July 1996.iso / vol_300 / 314_01 / timer.asm < prev   
Assembly Source File  |  1990-05-14  |  5KB  |  190 lines
  1.     title    timers.. timerins, timerrem, and timerint
  2.     page    60,132
  3. ;==============================================================================
  4. ;
  5. ;                   The Microcom MNP Library
  6. ;                    (Microsoft C Version)
  7. ; 
  8. ;------------------------------------------------------------------------------
  9. ;
  10. ;    timerins -- timer install routine
  11. ;
  12. ;    synopsis: timerins();
  13. ;
  14. ;------------------------------------------------------------------------------
  15. ;
  16. ;    timerrem -- timer remove routine
  17. ;
  18. ;    synopsis: timerrem();
  19. ;
  20. ;------------------------------------------------------------------------------
  21. ;
  22. ;    timerint -- timer interrupt routine (invoked on timer tick)
  23. ;
  24. ;------------------------------------------------------------------------------
  25. ;
  26. ;    Modification History
  27. ;
  28. ;    10/29/87 - timerint allowed to run with interrupts enabled..gp
  29. ;
  30. ;==============================================================================
  31.  
  32.     extrn    _tmr:word
  33.  
  34. _data    segment word public 'DATA'
  35. _data   ends
  36. dgroup  group    _data
  37.  
  38. _data   segment
  39. old_t_vct    label    dword        ; old timer vector contents
  40. old_bx        dw    0        ; base
  41. old_es        dw    0        ; segment
  42. timer_active    db    0        ; timer active flag
  43. tick        db    18        ; clock tick count
  44.  
  45. timer_no  equ    6            ; number of timers in table
  46. _data    ends
  47.  
  48. _text    segment byte public 'CODE'
  49.     assume    cs:_text,ds:dgroup
  50.  
  51.     public    _timerins,_timerrem
  52.     public    cdsg
  53.     public     _timer_int
  54.  
  55.  
  56. ; Data in code segment
  57. cdsg    dw    0
  58.  
  59.     page
  60. ;PUBLIC***********************************************************************
  61. ;
  62. ;    timerins - timer installation routine
  63. ;
  64. ;*****************************************************************************
  65.  
  66. _timerins proc near
  67.  
  68.     push    bp
  69.     push    es                ; save es and ds
  70.     push    ds
  71.  
  72. ; Check to be sure that the timer interrupt handler is not already
  73. ; installed.  Do nothing in this case.
  74.     cmp    timer_active,1        ; already installed?
  75.     je    tin9                ; yes-go return
  76.  
  77. ; Initialize
  78.     mov    timer_active,1        ; set timer active flag
  79.     mov    cs:cdsg,ds        ; save data segment
  80.  
  81. ; Save current interrupt vector contents then install our own handler.
  82.     mov    ah,35h            ; get vector request
  83.     mov    al,1ch            ; we want the timer one
  84.     int    21h                ; int to DOS
  85.     mov    old_bx,bx            ; save vector contents
  86.     mov    old_es,es
  87.     mov    dx,offset _timer_int    ; point to our handler
  88.     mov    ax,cs            ; be sure ds is right
  89.     mov    ds,ax
  90.     mov    ah,25h            ; set vector request
  91.     mov    al,1ch            ; we want the timer one
  92.     int    21h                ; int to DOS
  93.  
  94. ; Return
  95. tin9:
  96.     pop    ds                ; restore data segment
  97.     pop    es                ; restore es
  98.     pop    bp
  99.     ret
  100.  
  101. _timerins endp
  102.      page
  103. ;PUBLIC***********************************************************************
  104. ;
  105. ;    timerrem - timer removal subroutine
  106. ;
  107. ;*****************************************************************************
  108.  
  109. _timerrem proc near
  110.  
  111.     push    bp
  112. ; Check to be sure that the timer interrupt handler is already
  113. ; installed.  Do nothing if not.
  114.     cmp    timer_active,1        ; installed?
  115.     jne    tir9                ; no-go return
  116.  
  117. ; Recover old vector contents and put them back.
  118.     push    ds                ; save ds register
  119.     mov    ah,25h            ; set vector request
  120.     mov    al,1ch            ; we want the timer one
  121.     mov    dx,old_bx            ; recover old vector
  122.     mov    ds,old_es
  123.     int    21h                ; int to DOS
  124.     pop    ds                ; restore ds register
  125.     mov    timer_active,0        ; reset timer active flag
  126.  
  127. ; Return
  128. tir9:
  129.     pop    bp
  130.     ret
  131.  
  132. _timerrem endp
  133.     page
  134. ;*****************************************************************************
  135. ;
  136. ;    timerint - timer interrupt routine
  137. ;
  138. ;*****************************************************************************
  139.  
  140. _timer_int proc far
  141.  
  142. ; Initialize
  143.     push    ds                ; save registers
  144.     mov    ds,cs:cdsg        ; enable data addressability
  145.  
  146. ; Re-enable interrupts
  147. ;    sti
  148.  
  149. ; When a clock interrupt occurs, decrement the second ticker.  If the
  150. ; ticker goes to zero, count down the second-based timers.
  151. t1:
  152.     dec    tick                ; decrement ticker
  153.     jnz    tiret            ; go on if not zero
  154.  
  155. ; Pass through second-based timers and decrement any that are not already
  156. ; zero.  Zero can mean either 'elapsed' or 'inactive'.
  157. ti1:
  158.     mov    tick,18             ; reset ticker
  159.  
  160.     push    bx                ; save registers
  161.     push    cx
  162.     mov     bx,offset _tmr
  163.     mov    cx,timer_no        ; do for each timer
  164.  
  165. ti3:
  166.     cmp    word ptr [bx],0     ; active?
  167.     je    ti4                ; no-go on
  168.     dec    word ptr [bx]        ; yes-count it down
  169.  
  170. ti4:
  171.     add    bx,2                ; advance to next timer
  172.     loop    ti3                ; and try again
  173.  
  174.     pop    cx                ; restore registers
  175.     pop    bx                ; and go on
  176.  
  177. tiret:
  178.     cli                    ;  disable interrupts before call
  179.     pushf                ; this is to simulate an int instruction
  180.     call    old_t_vct            ; inter-segment indirect call
  181.  
  182.     pop    ds
  183.     sti                    ; re-enable interrupts
  184.     iret                    ; and return from interrupt
  185.  
  186. _timer_int endp
  187.  
  188. _text    ends
  189.     end
  190.